Old Tersamian Sound Changes

Contents

Old Tersamian broke off from the Proto-Skomi branch 5000 years before present, when the original Tersamian peoples migrated south to the Ältojowa plain. Between the 2500 years between their arrival to the Ältojowa plain and the establishment of the First Tersamian Empire, a seismic shift in the phonological characteristics of Old Tersamian occurred.

Notably,

  1. Voiced plosives lenitioned to voiced fricatives.
  2. A new set of unvoiced nasals were formed from voiced nasals.
  3. 5 diphthongs (ʉ̯ə, ɵʉ̯, ɛ̯ɐ, ɨ̯ə, ɤɨ̯) were created by the merger of /ə/ and another vowel.
  4. Vowels after root vowels cause the root vowel to lengthen.
  5. Syllable structure complexity increased from (C)(C)V(C)(C) to (C)(C)(C)V(C)(C)(C), subject to certain conditions.

The following sections detail the individual sound changes that took place and the time period that it took effect. The sound changes are written for the Lexurgy sound changer, which can handle complex consonant clusters, metathesis and diacritics without a hitch.

I intend to add time periods later but I’m busy right now.

Lexurgy Sound Change Rules

Feature +stress, +aspiration, +throwaway0, +throwaway1, +long
Diacritic ː [+long]
Diacritic ˈ (floating) [+stress]
Diacritic ʰ [+aspiration]
Diacritic ̥ [+throwaway0]
Diacritic ̊ [+throwaway1]
Symbol ɨ̯ə, ɤɨ̯, ʉ̯ə, ɵʉ̯, ɛ̯ɐ
Class consonant {m, m̥, n, n̥, ŋ, ŋ̊, p, pʰ, b, t, tʰ, d, c, cʰ, k, kʰ, g, ʔ, v, s, sʰ, z, ɣ, h, ɦ, l, r, ɾ, j, ɥ, w}
Class voiced {m, n, ŋ, b, d, g, v, z, ɣ, ɦ, l, r, ɾ, j, ɥ, w}
Class unvoiced {m̥, n̥, ŋ̊, p, pʰ, t, tʰ, c, cʰ, k, kʰ, ʔ, s, sʰ, h}
Class plosive {p, pʰ, b, t, tʰ, d, c, cʰ, k, kʰ, g, ʔ}
Class liquid {l, r, ɾ}
Class glide {j, ɥ, w}
Class fricative {v, s, sʰ, z, ɣ, h, ɦ}
Class hfric {h, ɦ}
Class zfric {v, s, sʰ, z, ɣ}
Class sfric {v, s, sʰ, z}
Class nasal {m, m̥, n, n̥, ŋ, ŋ̊}
Class vowel {i, ɪ, iː, ɨ̯ə, e, ɛ, eː, ɤɨ̯, a, aː, ɑ, ɑː, ɛ̯ɐ, ə, u, ʊ, uː, ʉ̯ə, o, ɔ, oː, ɵʉ̯}
Class front {i, ɪ, iː, e, ɛ, eː, ɛ̯ɐ, ʉ̯ə, ɵʉ̯}
Class back {ɨ̯ə, ɤɨ̯, a, aː, ɑ, ɑː, u, ʊ, uː, o, ɔ, oː}
Class moved {ɓ, ɗ, ʄ, ɠ, ʛ}
Syllables:
    explicit

glottal-fricative-removal cleanup:
    {h, ɦ} => * / _ {x, ɣ}

approximant-simplification cleanup:
    w => * / @consonant _ j
    w j => ɥ * // $ _
    j w => ɥ * / _ {@consonant, $}
    j => * / {j, ɥ} _
    
degemination cleanup:
    {rr, ɾr, rɾ, ɾɾ} => r
    @consonant$1 $1 => $1 *
    @hfric => * / _ @hfric

delengthen cleanup:
    @vowel&[-stress]$1 $1 => $1 *

assimilation-of-b:
    b => * / {m _, _ m}

lenition-of-plosives-before-nasals:
    {p, pʰ, t, tʰ, k, kʰ} => {b, p, d, t, g, k}	/ _ {m, n, ŋ}

lenition-of-b:
    b => v

lenition-of-d:
    d => ɾ // {n _, _ {r, j}}

lenition-of-g:
    gj => z
    Then: g => ɣ // {l _, _ l, $ _ ə}
    Then: g => ɦ

iotacisation-of-l:
    l => j / tʰ _

sibilantisation-of-th:
    tʰ => sʰ

lenition-of-g2:
    g => ɦ / {l _, _ l}

lenition-of-d2:
    d => z / n _
    Then: dj => z
    Then: dr => ɦl

collapse-of-s-plosive:
    s {p, pʰ, t, tʰ, k, kʰ} => tʰ / _ $
    Then: {p, pʰ, t, tʰ, k, kʰ} s => tʰ / _ @vowel
    Then: s => * / {_ {p, pʰ, tʰ, k, kʰ}, {pʰ, tʰ, kʰ} _}

aspiration-before-s:
    {p,k} s => {pʰ,tʰ} *

debuccalisation-of-t-around-s:
    t => ʔ / {s _, _ s}

nasal-assimilation propagate:
    {n,ŋ} => m / _ {m, v, p, pʰ}
    {m,ŋ} => n / _ {n, s, z, d, ɾ, r, t, tʰ}
    {m,n} => ŋ / _ {ŋ, ɣ, g, k, kʰ}

raising-of-e-around-j:
    {ej,je} => i // {s, sʰ, z} _

# raising-of-o-near-u:
    # o => u / _ @consonant* u

deletion-of-h-before-j:
    h => * / _ j

palatalisation-of-velar-plosives:
    {k, kʰ} j => {c, cʰ} *

iotacisation-of-l2:
    l => j / {s, tʰ} _

unvoicing-of-nasals:
    {s, h, ʔ} {m, n, ŋ} => * {m̥, n̥, ŋ̊}
    {m, n, ŋ} {s, h} => {m̥, n̥, ŋ̊} *
    {ʔ / {m, m̥} _, ʔ / {n, n̥} _, ʔ / {ŋ, ŋ̊} _} => {p, t, k}
    Then: {m, n, ŋ} => {m̥, n̥, ŋ̊} / {@unvoiced _, _ @unvoiced}

# debuccalisation-of-plosives-after-nasal:
    # {p / {m, m̥} _, t / {n, n̥} _, k / {ŋ, ŋ̊} _} => ʔ

lowering-of-vowels-around-h:
    h {a, e, i, o, u} => * {a, e, e, a, o}
    {a, e, i, o, u} h => {a, e, e, a, o} *

debuccalisation-of-s:
    s => h // {_ {p, pʰ, t, tʰ, k, kʰ, l, j, ʔ}, {ʔ, l} _}

raising-of-vowels-near-glottal-stop:
    ʔ (@consonant*)$1 {a,e,i,o,u} => * $1 {e,i,i,u,u}
    {a,e,i,o,u} (@consonant*)$1 ʔ => {e,i,i,u,u} $1 *

raising-of-o-near-w:
    o => u / {w _, _ w}

devoicing-of-l-before-s:
    l => n̥ / _ s

i-led-metathesis:
    # mark e,a,o,u as up for metathesis
    {e, a, o, u}&[-stress] => {ɓ, ɗ, ʄ, ɠ} / i @consonant* _
    Then:
    # add q to the end of all valid consonant clusters
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / @vowel _ @vowel
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved?)$1 * => $1 q / @vowel _ $
    (@moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / $ _ @vowel
    Then:
    # convert target nucleus based on trigger vowel
    {i,iˈ} => {je, jeˈ} / _ @consonant* ɓ @consonant* q
    {i,iˈ} => {jɛ̯ɐ, jɛ̯ɐˈ} / _ @consonant* ɗ @consonant* q
    {i,iˈ} => {jɵʉ̯, jɵʉ̯ˈ} / _ @consonant* ʄ @consonant* q
    {i,iˈ} => {jʉ̯ə, jʉ̯əˈ} / _ @consonant* ɠ @consonant* q
    Then:
    # remove trigger vowel if it leaves behind a valid consonant cluster
    @moved => * / _ @consonant* q
    Then:
    # clean up
    jˈ => j
    {ɓ, ɗ, ʄ, ɠ} => {e, a, o, u}
    q => *

lowering-of-i-after-alveolars:
    i => je / {l, n, ɾ} _

lowering-after-unvoiced:
    {u, i, e, o} => {o, e, ɛ̯ɐ, a} / @unvoiced ({r, l, j, w})? _

lengthening-of-vowels:
    # mark vowels for metathesis
    a => ɓ / aˈ @consonant* _
    {a, e, i} => {ɓ, ɗ, ʄ} / eˈ @consonant* _
    i => ʄ / iˈ @consonant* _
    o => ɠ / oˈ @consonant* _
    {o, u} => {ɠ, ʛ} / uˈ @consonant* _
    Then:
    # add q to the end of all valid consonant clusters
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / @vowel _ @vowel
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved?)$1 * => $1 q / @vowel _ $
    (@moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / $ _ @vowel
    Then:
    aˈ => aːˈ / _ @consonant* ɓ @consonant* q
    eˈ => eːˈ / _ @consonant* {ɓ, ɗ, ʄ} @consonant* q
    iˈ => iːˈ / _ @consonant* ʄ @consonant* q
    oˈ => oːˈ / _ @consonant* ɠ @consonant* q
    uˈ => uːˈ / _ @consonant* {ɠ, ʛ} @consonant* q
    Then:
    @moved => * / _ @consonant* q
    Then:
    {ɓ, ɗ, ʄ, ɠ, ʛ} => {a, e, i, o, u}
    q => *

front-vowel-syllable-merging:
    {i, e} j ə => * j ɛ̯ɐ

raising-after-voiced:
    # x is a placeholder
    {a, e, o, ɛ̯ɐ, ɤɨ̯, ɵʉ̯} => {jx, i, u, je, ɨ̯ə, ʉ̯ə} / @voiced _ // {$, @unvoiced} ({r, ɾ})? @glide? _
    Then: jˈ => j
    Then: x => e / {@front @consonant* _, _ @consonant* @front} // {@back @consonant* _, _ @consonant* @back}
    Then: x => o

metathesis-of-i-and-u:
    # mark vowels for metathesis
    i => ʄ / {a, o, u, ɛ̯ɐ, ɵʉ̯, ʉ̯ə} @consonant* _
    {o, u} => {ɠ, ʛ} / {a, e, i, ɛ̯ɐ, ɤɨ̯, ɨ̯ə} @consonant* _
    Then:
    # add q to the end of all valid consonant clusters
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / @vowel _ @vowel
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved?)$1 * => $1 q / @vowel _ $
    (@moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / $ _ @vowel
    Then:
    * => j / {a, o, u, ɛ̯ɐ, ɵʉ̯, ʉ̯ə} _ @consonant* ʄ @consonant* q
    * => w / {a, e, i, ɛ̯ɐ, ɤɨ̯, ɨ̯ə} _ @consonant* {ɠ, ʛ} @consonant* q
    Then:
    @moved => * / _ @consonant* q
    Then:
    {ɓ, ɗ, ʄ, ɠ, ʛ} => {a, e, i, o, u}
    q => *

centralisation-near-schwa @vowel:
    { {a, aː}, {e, eː}, {i, iː}, {o, oː}, {u, uː}} => {ɛ̯ɐ, ɤɨ̯, ɨ̯ə, ɵʉ̯, ʉ̯ə} / {ə _, _ ə}

lowering-of-e-around-j-and-w:
    j e => * ɛ̯ɐ / @consonant _ w

simplification-of-eje:
    əjə => eː

raising-of-vowels-after-j:
    jə => ji
    je => ji / _ $
    Then:
    $$ => * / _ ji

formation-of-labial-palatal-approximant:
    j => ɥ / _ {u, uː, ʉ̯ə}
    Then: {w j, j w} => ɥ
    Then: w => ɥ / _ iː
    Then: w i => ɥ * / @vowel _ {@consonant, $}

u-and-o-diphthong-simplification:
    {ʉ̯ə, ɵʉ̯} j => eː * / _ {@consonant, $}
    {ʉ̯ə, ɵʉ̯} ɥ => ɵʉ̯ * / _ {@consonant, $}

removal-of-interconsonantal-h:
    @hfric => * / @consonant _ @consonant

reemergence-of-h:
    {ɣ, ɦ} r => ɦ *
    kʰ r =>	h *

deletion-of-schwa propagate:
    # mark vowels for metathesis
    ə&[-stress] => ɓ
    Then:
    # add q to the end of all valid consonant clusters
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / @vowel _ @vowel
    ({@moved? @consonant?, @moved? @glide? @moved? {@liquid? @moved? @plosive, @liquid? @moved? @zfric, @nasal, @nasal @moved? @zfric, @nasal @moved? @plosive}} @moved?)$1 * => $1 q / @vowel _ $
    (@moved? {@consonant?, {@plosive @moved? @liquid?, @fricative @moved? @liquid?, @hfric @moved? @sfric @moved? @liquid? @moved?, @fricative? @moved? @nasal, @plosive @moved? @zfric} @moved? @glide?} @moved?)$1 * => $1 q / $ _ @vowel
    Then:
    @moved => * / _ @consonant* q
    Then:
    ɓ => ə
    q => *

shifting-of-schwa:
    ə => o / _ @consonant
    ə => ɤɨ̯ / _ {@vowel, $}

resolving-of-glottal-stops:
    ʔ => t / {n, l} _
    ʔ => c / j _

debuccalisation-of-r:
    r => ɣ / {p, pʰ} _

vowel-quality-shift:
    {a, e, i, o, u} => {ɑ, ɛ, ɪ, ɔ, ʊ}
    aː => ɑː

vowel-plus-glide-to-long-vowel:
    {ɛj, ɔw} => {eː,oː} / _ @consonant
    {ɪj, ʊw} => {iː, uː}

deletion-of-glide-after-high-vowels:
    ɥ => * / ʉ̯ə _
    j => * / iː _
    w => * / uː _

deletion-of-h-before-voiced-consonant:
    ɦ => * / @vowel _ @voiced

raising-of-ou-before-r:
    ɵʉ̯ => ʊ / _ ɾ

deletion-of-h-before-glide:
    h => * / _ {w, ɥ}